msolveRealSolutions -- compute all real solutions to a zero dimensional system using symbolic methods

Usage:

msolveRealSolutions(I)

msolveRealSolutions(I, K)
Inputs:
- I, an ideal, which is zero dimensional, in a polynomial ring with coefficients over QQ
- K, a ring or an instance of the type RingFamily, the field to find answers in, which must be one of QQi (default), QQ, RR, or RRi (possibly with specified precision)
Optional inputs:
- Threads => an integer, default value 5, number of processor threads to use;
- Verbosity => an integer, default value 0, level of verbosity between 0, 1, and 2;
Outputs:
- a list, of lists; each entry in the list consists of a list representing the coordinates of a solution. By default each solution coordinate value is also represented by a rational interval consisting of a two element list of rational numbers, {a, b}, this means that that coordinate of the solution has a value greater than or equal to a and less than or equal to b. This interval is computed symbolically and its correctness is guaranteed by exact methods.

Description

This functions uses the msolve package to compute the real solutions to a zero dimensional polynomial ideal with either integer or rational coefficients.

The second input is optional, and indicates the alternative ways to provide output either using an exact rational interval QQi, a real interval RRi, or by taking a rational or real approximation of the midpoint of the intervals.

i1 : R = QQ[x,y]

o1 = R

o1 : PolynomialRing

i2 : I = ideal {(x-1)*x, y^2-5}

             2       2
o2 = ideal (x  - x, y  - 5)

o2 : Ideal of R

i3 : rationalIntervalSols = msolveRealSolutions I

        18446744073709551615  18446744073709551617    41248173712355948587 
o3 = {{{--------------------, --------------------}, {--------------------,
        18446744073709551616  18446744073709551616    18446744073709551616 
     ------------------------------------------------------------------------
     10312043428088987147                      72708440307               
     --------------------}}, {{- ---------------------------------------,
      4611686018427387904        340282366920938463463374607431768211456 
     ------------------------------------------------------------------------
                   50882082555                  41248173712355948587 
     ---------------------------------------}, {--------------------,
     340282366920938463463374607431768211456    18446744073709551616 
     ------------------------------------------------------------------------
     10312043428088987147      18446744073709551615  18446744073709551617  
     --------------------}}, {{--------------------, --------------------},
      4611686018427387904      18446744073709551616  18446744073709551616  
     ------------------------------------------------------------------------
        10312043428088987147    41248173712355948587       
     {- --------------------, - --------------------}}, {{-
         4611686018427387904    18446744073709551616       
     ------------------------------------------------------------------------
                    9521974700326754379833418737               
     ---------------------------------------------------------,
     784637716923335095479473677900958302012794430558004314112 
     ------------------------------------------------------------------------
                    82235864872950540370276368309                   
     ----------------------------------------------------------}, {-
     6277101735386680763835789423207666416102355444464034512896     
     ------------------------------------------------------------------------
     10312043428088987147    41248173712355948587
     --------------------, - --------------------}}}
      4611686018427387904    18446744073709551616

o3 : List

i4 : rationalApproxSols = msolveRealSolutions(I, QQ)

          82496347424711897175                    2728294719               
o4 = {{1, --------------------}, {- --------------------------------------,
          36893488147419103232      85070591730234615865843651857942052864 
     ------------------------------------------------------------------------
     82496347424711897175         82496347424711897175  
     --------------------}, {1, - --------------------},
     36893488147419103232         36893488147419103232  
     ------------------------------------------------------------------------
                      6060067270336505331609018413                  
     {-----------------------------------------------------------, -
      12554203470773361527671578846415332832204710888928069025792   
     ------------------------------------------------------------------------
     82496347424711897175
     --------------------}}
     36893488147419103232

o4 : List

i5 : floatIntervalSols = msolveRealSolutions(I, RRi)

o5 = {{[1,1], [2.23607,2.23607]}, {[-2.13671e-28,1.49529e-28],
     ------------------------------------------------------------------------
     [2.23607,2.23607]}, {[1,1], [-2.23607,-2.23607]},
     ------------------------------------------------------------------------
     {[-1.21355e-29,1.31009e-29], [-2.23607,-2.23607]}}

o5 : List

i6 : floatIntervalSols = msolveRealSolutions(I, RRi_10)

o6 = {{[.999999,1], [2.23607,2.23607]}, {[-3.20841e-9,3.49147e-9],
     ------------------------------------------------------------------------
     [2.23607,2.23607]}, {[.999999,1], [-2.23607,-2.23607]},
     ------------------------------------------------------------------------
     {[-3.50087e-10,1.15444e-10], [-2.23607,-2.23607]}}

o6 : List

i7 : floatApproxSols = msolveRealSolutions(I, RR)

o7 = {{1, 2.23607}, {-3.2071e-29, 2.23607}, {1, -2.23607}, {4.82712e-31,
     ------------------------------------------------------------------------
     -2.23607}}

o7 : List

i8 : floatApproxSols = msolveRealSolutions(I, RR_10)

o8 = {{1, 2.23607}, {1.4153e-10, 2.23607}, {1, -2.23607}, {-1.17321e-10,
     ------------------------------------------------------------------------
     -2.23607}}

o8 : List

Note in cases where solutions have multiplicity this is not reflected in the output. While the solver does not return multiplicities, it reliably outputs the verified isolating intervals for multiple solutions.

i9 : I = ideal {(x-1)*x^3, (y^2-5)^2}

             4    3   4      2
o9 = ideal (x  - x , y  - 10y  + 25)

o9 : Ideal of R

i10 : floatApproxSols = msolveRealSolutions(I, RRi)

o10 = {{[1,1], [2.23607,2.23607]}, {[-2.13671e-28,1.49529e-28],
      -----------------------------------------------------------------------
      [2.23607,2.23607]}, {[1,1], [-2.23607,-2.23607]},
      -----------------------------------------------------------------------
      {[-1.21355e-29,1.31009e-29], [-2.23607,-2.23607]}}

o10 : List

Ways to use msolveRealSolutions:

msolveRealSolutions(Ideal)
msolveRealSolutions(Ideal,Ring)
msolveRealSolutions(Ideal,RingFamily)

For the programmer

The object msolveRealSolutions is a method function with options.

The source of this document is in Msolve.m2:644:0.